2ο ΓΕΛ Γέρακα - ΠΛΗΡΟΦΟΡΙΚΗ - ΛΥΣΕΙΣ ΤΡΑΠΕΖΑΣ ΘΕΜΑΤΩΝ 33444

e-ΜΑΘΗΜΑΤΑ
ΠΛΗΡΟΦΟΡΙΚΗ
Λύσεις ασκήσεων Τράπεζας Θεμάτων
33444

ΠΡΟΓΡΑΜΜΑ εκατομμυριοστός_πελάτης_ΤΘ_33444



!ΘΕΜΑ 4

!Ο εκατομμυριοστός πελάτης ενός πολυκαταστήματος λαμβάνει από τη Διεύθυνση

!του πολυκαταστήματος ως δώρο το ποσό των 1000 ευρώ, το οποίο μπορεί να διαθέσει

!για αγορές εντός του πολυκαταστήματος. Να γράψετε πρόγραμμα σε ΓΛΩΣΣΑ το οποίο:

!

!4.1 Να περιλαμβάνει κατάλληλο τμήμα δηλώσεων.

! Για κάθε είδος που επιθυμεί να αγοράσει ο πελάτης να διαβάζει την ονομασία είδους

! και την τιμή αγοράς του σε ευρώ. Κατά την εισαγωγή της τιμής αγοράς πρέπει

! να ελέγχεται ότι δίνεται θετικός αριθμός.

! Στην περίπτωση που εισάγεται άκυρη τιμή, το πρόγραμμα πρέπει να ζητάει νέα τιμή

! μέχρι να δοθεί θετικός αριθμός.

! Αν το υπόλοιπο χρημάτων επαρκεί για την αγορά, τότε θα εμφανίζεται το μήνυμα

! "Επιτυχής αγορά" και θα αφαιρείται η τιμή αγοράς από το υπόλοιπο.

! Διαφορετικά θα εμφανίζεται το μήνυμα "Δεν επαρκεί το υπόλοιπο".

! Η διαδικασία των αγορών θα τερματίζεται είτε όταν ως ονομασία είδους δοθεί

! η λέξη ΤΕΛΟΣ, είτε όταν μηδενισθεί το υπόλοιπο των χρημάτων.

!Μονάδες 15

!

!4.2 Να εμφανίζει την ονομασία του ακριβότερου είδους που αγοράστηκε,

! καθώς και η τιμή αγοράς του. Θεωρείστε ότι θα αγοραστεί τουλάχιστον ένα είδος.

!Μονάδες 5

!

!4.3 Να εμφανίζει το πλήθος των ειδών που δεν αγοράστηκαν γιατί δεν επαρκούσε

! το υπόλοιπο. Στην περίπτωση που δεν ξοδεύτηκε όλο το ποσό, να εμφανίζει το ποσό

! που περίσσεψε. Διαφορετικά να εμφανίζει το μήνυμα "Μηδενικό υπόλοιπο".

!Μονάδες 5





ΜΕΤΑΒΛΗΤΕΣ

  ΧΑΡΑΚΤΗΡΕΣ: Ονομασία, Ακριβότερο

  ΠΡΑΓΜΑΤΙΚΕΣ: Τιμή, Υπόλοιπο, Μέγιστη

  ΑΚΕΡΑΙΕΣ: ΠλήθοςΑπορριφθέντων

ΑΡΧΗ

  Υπόλοιπο <- 1000

  Μέγιστη <- -1

  Ακριβότερο <- ''

  ΠλήθοςΑπορριφθέντων <- 0



! Επανάληψη μέχρι να τελειώσουν τα λεφτά ή να δοθεί ΤΕΛΟΣ

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ

    ΓΡΑΨΕ 'Δώσε ονομασία είδους (ή ΤΕΛΟΣ για τερματισμό): '

    ΔΙΑΒΑΣΕ Ονομασία



    ΑΝ Ονομασία <> 'ΤΕΛΟΣ' ΤΟΤΕ

!     Διάβασε τιμή με έλεγχο θετικότητας

      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ

        ΓΡΑΨΕ 'Δώσε τιμή αγοράς (>0): '

        ΔΙΑΒΑΣΕ Τιμή

      ΜΕΧΡΙΣ_ΟΤΟΥ Τιμή > 0



      ΑΝ Τιμή <= Υπόλοιπο ΤΟΤΕ

        ΓΡΑΨΕ 'Επιτυχής αγορά'

        Υπόλοιπο <- Υπόλοιπο - Τιμή



!       Έλεγχος για ακριβότερο

        ΑΝ Τιμή > Μέγιστη ΤΟΤΕ

          Μέγιστη <- Τιμή

          Ακριβότερο <- Ονομασία

        ΤΕΛΟΣ_ΑΝ

      ΑΛΛΙΩΣ

        ΓΡΑΨΕ 'Δεν επαρκεί το υπόλοιπο'

        ΠλήθοςΑπορριφθέντων <- ΠλήθοςΑπορριφθέντων + 1

      ΤΕΛΟΣ_ΑΝ

    ΤΕΛΟΣ_ΑΝ

  ΜΕΧΡΙΣ_ΟΤΟΥ Ονομασία = 'ΤΕΛΟΣ' Η Υπόλοιπο = 0



! 4.2 Ακριβότερο είδος

  ΓΡΑΨΕ 'Ακριβότερο είδος: ', Ακριβότερο, ' με τιμή: ', Μέγιστη



! 4.3 Μη αγορασμένα και υπόλοιπο

  ΓΡΑΨΕ 'Πλήθος ειδών που δεν αγοράστηκαν: ', ΠλήθοςΑπορριφθέντων

  ΑΝ Υπόλοιπο = 0 ΤΟΤΕ

    ΓΡΑΨΕ 'Μηδενικό υπόλοιπο'

  ΑΛΛΙΩΣ

    ΓΡΑΨΕ 'Υπόλοιπο χρημάτων: ', Υπόλοιπο

  ΤΕΛΟΣ_ΑΝ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ