2ο ΓΕΛ Γέρακα - ΠΛΗΡΟΦΟΡΙΚΗ - ΛΥΣΕΙΣ ΤΡΑΠΕΖΑΣ ΘΕΜΑΤΩΝ 33032

e-ΜΑΘΗΜΑΤΑ
ΠΛΗΡΟΦΟΡΙΚΗ
Λύσεις ασκήσεων Τράπεζας Θεμάτων
33032

ΠΡΟΓΡΑΜΜΑ πρωτάθλημα_ΤΘ_33032

!ΘΕΜΑ 4

!Στο πρωτάθλημα Α' εθνικής συμμετέχουν 16 ομάδες που δίνουν 15 Χ 2 αγώνες.

!Η ομάδα 1 δεν αγωνίζεται με την ομάδα 1, η 2 με την 2 κοκ).

!Να αναπτύξετε ένα πρόγραμμα σε ΓΛΩΣΣΑ το οποίο:

!4.1

!Περιλαμβάνοντας κατάλληλο τμήμα δηλώσεων, να διαβάζει τα ονόματα των 16 ομάδων

!και να τα καταχωρεί σε κατάλληλο πίνακα.

!Μονάδες 6

!4.2

!Να διαβάζει τη βαθμολογία των 15 αγώνων του πρώτου γύρου των 16 ομάδων

!και να ελέγχει τη σωστή εισαγωγή δεδομένων (2, 1 ή 0).

!(Στην περίπτωση που καταχωρηθεί 2 -νίκη- στην αντίπαλη ομάδα καταχωρείται 0,

! στην περίπτωση ισοπαλίας και στις δύο ομάδες καταχωρείται 0     ( *** 1)

! και στην περίπτωση ήττας στην αντίπαλη ομάδα 2).

!Μονάδες 8

!4.3

!Να υπολογίζει το άθροισμα της βαθμολογίας κάθε ομάδας.

!Μονάδες 5

!4.4

!Να βρίσκει την πρωταθλήτρια ομάδα και να εμφανίζει το όνομά της.

!(Υποθέστε ότι μία μόνο ομάδα έχει την υψηλότερη βαθμολογία).

!Μονάδες 6





! -----------------------

! Σχόλια για καλύτερη κατανόηση της εκφώνησης.

! Η εκφώνηση λέει ότι καταχώριση 2 σημαίνει νίκη του γηπεδούχου.

! Δεν είναι ΠΡΟ-ΠΟ   1 - X - 2

!

! Επίσης η ενδεικτική λύση δίνει 1 βαθμό στην ισοπαλία και όχι 0 όπως λέει η εκφώνηση.

! Η εκφώνηση δίνει 2 βαθμούς στη νίκη. (Είναι παλιά Α εθνική, όχι Champion League...)

! -----------------------





ΜΕΤΑΒΛΗΤΕΣ

  ΧΑΡΑΚΤΗΡΕΣ: ΟΜΑΔΕΣ[16] 

  ΑΚΕΡΑΙΕΣ: ΑΓΩΝΕΣ[16, 16], ΒΑΘΜΟΙ[16], i, j, ΜΑΧ, ΘΕΣΗ

ΑΡΧΗ



! 4.1 Εισαγωγή ονομάτων ομάδων

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 16

    ΔΙΑΒΑΣΕ ΟΜΑΔΕΣ[i] 

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ



! 4.2 Εισαγωγή αποτελεσμάτων αγώνων

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 16

    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 16

      ΑΝ (i <> j) ΤΟΤΕ            ! Καμιά ομάδα δεν δίνει αγώνα με τον εαυτό της

        ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ

          ΓΡΑΨΕ 'Δώσε αποτέλεσμα αγώνα ', ΟΜΑΔΕΣ[i], ' - ', ΟΜΑΔΕΣ[j] 

          ΓΡΑΨΕ '(2=νίκη 1ης, 0=ήττα 1ης, 1=ισοπαλία): '

          ΔΙΑΒΑΣΕ ΑΓΩΝΕΣ[i, j] 

        ΜΕΧΡΙΣ_ΟΤΟΥ (ΑΓΩΝΕΣ[i, j] = 2) Η (ΑΓΩΝΕΣ[i, j] = 1) Η (ΑΓΩΝΕΣ[i, j] = 0) 

      ΑΛΛΙΩΣ

        ΑΓΩΝΕΣ[i, j] <- 0

      ΤΕΛΟΣ_ΑΝ

    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ



! 4.3. Υπολογισμός βαθμολογίας ομάδων με βάση τα αποτελέσματα των αγώνων

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 16

    ΒΑΘΜΟΙ[i] <- 0

    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 16

      ΑΝ (i <> j) ΤΟΤΕ

        ΑΝ (ΑΓΩΝΕΣ[i, j] = 2) ΤΟΤΕ

          ΒΑΘΜΟΙ[i] <- ΒΑΘΜΟΙ[i] + 2                  ! κερδίζει ο i , χάνει ο j

          ΒΑΘΜΟΙ[j] <- ΒΑΘΜΟΙ[j] + 0

        ΑΛΛΙΩΣ_ΑΝ (ΑΓΩΝΕΣ[i, j] = 1) ΤΟΤΕ

          ΒΑΘΜΟΙ[i] <- ΒΑΘΜΟΙ[i] + 1                                  ! ισόπαλοι

          ΒΑΘΜΟΙ[j] <- ΒΑΘΜΟΙ[j] + 1

        ΑΛΛΙΩΣ

          ΒΑΘΜΟΙ[i] <- ΒΑΘΜΟΙ[i] + 0                  ! κερδίζει ο j , χάνει ο i

          ΒΑΘΜΟΙ[j] <- ΒΑΘΜΟΙ[j] + 2

        ΤΕΛΟΣ_ΑΝ

      ΤΕΛΟΣ_ΑΝ

    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ



! 4.4 Εύρεση πρωταθλήτριας ομάδας

  ΜΑΧ <- ΒΑΘΜΟΙ[1] 

  ΘΕΣΗ <- 1

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 16

    ΑΝ ΒΑΘΜΟΙ[i] > ΜΑΧ ΤΟΤΕ

      ΜΑΧ <- ΒΑΘΜΟΙ[i] 

      ΘΕΣΗ <- i

    ΤΕΛΟΣ_ΑΝ

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ ΟΜΑΔΕΣ[ΘΕΣΗ] 

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ